apply plugin: 'com.android.library'
apply plugin: 'maven'
apply plugin: 'signing'
apply plugin: 'nexus-workflow'

group = "com.snilius.aboutit"
archivesBaseName = "aboutit-meta"
version = "1.0.0"

android {
    compileSdkVersion 23
    buildToolsVersion "23.0.1"

    defaultConfig {
        minSdkVersion 14
        targetSdkVersion 23
        versionCode 1
        versionName version
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
}

dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])
    compile 'com.android.support:appcompat-v7:23.0.1'
    compile project(':aboutit')
}


signing {
    sign configurations.archives
}

uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }

            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }

            pom.project {
                name 'AboutIt Meta'
                packaging 'jar'
                // optionally artifactId can be defined here
                description 'Library presets for AboutIt'
                url 'https://github.com/victorhaggqvist/AboutIt'

                scm {
                    connection 'scm:git:https://github.com/victorhaggqvist/AboutIt.git'
                    developerConnection 'scm:git:https://github.com/victorhaggqvist/AboutIt.git'
                    url 'https://github.com/victorhaggqvist/AboutIt'
                }

                licenses {
                    license {
                        name 'The Apache License, Version 2.0'
                        url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }

                developers {
                    developer {
                        id 'atriix'
                        name 'Victor Häggqvist'
                        email 'victor@snilius.com'
                    }
                }
            }
        }
    }
}